Victor Image Processing Library How-to Tips

Edge Detection with Matrix Convolution

This procedure supports grayscale and color images. In general, the steps are:

• establish the kernel values in an array of type Variant
• fill a byte array with the kernel values
  changing any negative number into the corresponding positive byte number:
  positive value = negative value + 256
• make sure the divisor is not zero
• call the matrix convolution function, matrixconvex()

Designing the Kernel

The kernel elements should be balanced and arranged to emphasize differences along the direction of the edge to be detected. For example, to detect horizontal lines use

-1 -1 -1 0 0 0 1 1 1 a 3 x 3 kernel

or

-1 -1 -1 -1 -1 -1 -1 -2 -2 -2 -2 -2 -2 -2 -3 -3 -3 -3 -3 -3 -3 0 0 0 0 0 0 0 3 3 3 3 3 3 3 2 2 2 2 2 2 2 1 1 1 1 1 1 1 a 7 x 7 kernel

In this example we use a very simple kernel of

    -5   0   0
     0   0   0
     0   0   5

Original	After matrix convolution

Edge Detection with Matrix Convolution - the Visual Basic Source Code

' Function Declaration ........................................... 
Declare Function matrixconvex Lib "VIC32.DLL" (ByVal ksize As Long, ByRef firstelement as byte, ByVal divsr As Long, srcimg As imgdes, resimg As imgdes) As Long

' The Function .................................................. 
Public Function diagonaledge(ByRef myimage As imgdes) As Long
Dim rcode As Long
Dim kernel(0 To 8) As Byte     ' 3 x 3 kernel
Dim kernelvalues As Variant
Dim j As Integer
Dim divisor As Long

divisor = 0

' Kernel values:
'    -5   0   0
'    0    0   0
'    0    0   5

kernelvalues = Array(-5, 0, 0, 0, 0, 0, 0, 0, 5)
    For j = 0 To 8
        If (kernelvalues(j) >= 0) Then
            kernel(j) = kernelvalues(j)
        Else
            kernel(j) = kernelvalues(j) + 256   ' Negative values have to be converted to corresponding positive values 
                                                '     -1 becomes 255 
        End If                                  '     -2 becomes 254, and so on 
        
        divisor = divisor + kernelvalues(j)
    Next j
        
    If (divisor = 0) Then divisor = 1           ' Make sure divisor is not zero  
    rcode = matrixconvex(3, kernel(0), divisor, myimage, myimage)
        
    diagonaledge = rcode

End Function

Victor Image Processing Library homepage | Victor Product Summary | more source code